451d2f946f
* feat: native Windows ARM64 build support Builds on the merged DEPS_ARCH=arm64 plumbing (#13424) by adding the dependency and source fixes needed for a green native ARM64 build on the windows-11-arm runner. Validated end-to-end on Snapdragon X Elite hardware (via a downstream fork using the same fixes); see OrcaSlicer/OrcaSlicer#8271 for the full writeup. Dependencies: - OpenEXR 2.5.5: ImfSimd.h hard-codes IMF_HAVE_SSE2 for any MSVC, pulling in <emmintrin.h> (x86-only) -> C1189. Patch the header to require an x86 target and force SSE cache vars off on ARM64. - Boost.Context: use the winfib implementation on ARM64 (Windows Fiber API) to avoid the armasm64 / CMake ASM_ARMASM linker-module bug, while keeping the Boost::context target Boost.Asio needs. - OpenCV: disable WITH_IPP on ARM64 (Intel IPP/IPP-ICV is x86/x64 only; otherwise ~200 unresolved ippicv* externals at link). - OpenSSL: use VC-WIN64-ARM on ARM64. - FindGLEW: add an ARM64 arch branch. Sources: - clipper Int128.hpp: _mul128 is an x64-only intrinsic guarded by _WIN64 (true on ARM64); guard on _M_X64 and use the portable path. - imgui imgui_widgets.cpp: fix va_start(vaList, &text) -> va_start(vaList, text) (the &-form compiled on x64 but is invalid on ARM64). - crash reporter: StackWalker.cpp gains an _M_ARM64 branch; BaseException.cpp uses Cpsr instead of the x86-only EFlags on ARM64. CI: - New build_windows_arm64.yml on windows-11-arm: pins CMake 3.31.x, stages ARM64 GMP/MPFR from MSYS2 clangarm64 (with llvm-dlltool import libs), caches deps with a fixed-depth hashFiles key, builds and uploads the binary. OCCT/STEP, SVG-to-3D and text emboss all build and work on ARM64 (no stubs needed). Full feature parity with x64. * fix(ci): use forward-slash DESTDIR to avoid CMake '\a' escape error deps configure failed at GMP/GMP.cmake: "Invalid character escape '\a'" because DESTDIR carried Windows backslashes (C:\a\...) and is re-parsed when re-set with the /usr/local suffix. Pass DESTDIR (and the slicer's DEPS prefix) with forward slashes via %CD:\=/%. * fix(ci): don't export DESTDIR env var (CMake staged-install doubles paths) Setting a DESTDIR *environment* variable made CMake treat it as the staged install prefix and prepend it to every dependency's install path, so e.g. FreeType installed to <DESTDIR>/a/.../OrcaSlicer_dep/usr/local and OCCT then couldn't find its headers. Compute the forward-slash path into a differently-named var (ORCA_DESTDIR) and pass it only via -DDESTDIR. * ci(windows-arm64): fold ARM64 build into the standard Windows matrix Replace the standalone build_windows_arm64.yml with a matrix entry on the existing build_windows job, so x64 and ARM64 share one reusable workflow chain (build_all -> build_check_cache -> build_deps -> build_orca), per review feedback on #14059. - build_all.yml: build_windows now matrices over {x64: windows-latest, arm64: windows-11-arm} and threads `arch` through. Self-hosted runner stays x64-only. - build_check_cache.yml: cache key and dep-prefix path are now architecture-specific on Windows (deps/build-arm64/OrcaSlicer_dep). - build_release_vs.bat: accept an `arm64` argument (mirrors build_release_vs2022.bat) -> uses `-A ARM64` and the build-arm64 tree. The top-level CMake auto-derives CMAKE_PREFIX_PATH from the build dir, so no explicit prefix is needed. - build_deps.yml / build_orca.yml: gate the ARM64-only prep behind `inputs.arch == 'arm64'` -- pin CMake 3.31.x, and stage MSYS2 clangarm64 GMP/MPFR import libs. NSIS installer/PDB/profile_validator remain x64-only; ARM64 ships the portable zip. Artifact names get an arch suffix to avoid collisions between the two Windows jobs. https://claude.ai/code/session_0164c7ZhCLsYBmCiVN9pWDjK * ci(temp): generate GMP/MPFR win-arm64 blobs to commit to repo * feat(deps): add prebuilt GMP/MPFR win-arm64 blobs The repo ships prebuilt GMP/MPFR import libs + DLLs for win-x64 and win-x86; the Windows ARM64 build path copies from win-${DEPS_ARCH} (CMakeLists.txt) but the win-arm64 blobs were missing, so the slicer configure failed at "file COPY cannot find .../win-arm64/libgmp-10.dll". Add win-arm64 libgmp-10.{dll,lib} and libmpfr-4.{dll,lib}, generated from the MSYS2 clangarm64 gmp/mpfr packages with MSVC-compatible import libs via llvm-dlltool. Headers are shared across arches and unchanged. * simplify OpenEXR.cmake * set default arch * support msix * ship installer * try to fix webview2runtime issue --------- Co-authored-by: Adam Behrman <adam.behrman@gmail.com> Co-authored-by: Claude <noreply@anthropic.com> Co-authored-by: Adam Behrman <abehrman@users.noreply.github.com>
360 lines
12 KiB
CMake
360 lines
12 KiB
CMake
# Distributed under the OSI-approved BSD 3-Clause License. See accompanying
|
||
# file Copyright.txt or https://cmake.org/licensing for details.
|
||
|
||
# PrusaSlicer specifics:
|
||
# This file is backported from CMake 3.15 distribution to behave uniformly
|
||
# across all versions of CMake. It explicitly adds GLEW_STATIC compile
|
||
# definition to static targets which is needed to prevent link errors.
|
||
|
||
#[=======================================================================[.rst:
|
||
FindGLEW
|
||
--------
|
||
|
||
Find the OpenGL Extension Wrangler Library (GLEW)
|
||
|
||
Input Variables
|
||
^^^^^^^^^^^^^^^
|
||
|
||
The following variables may be set to influence this module’s behavior:
|
||
|
||
``GLEW_USE_STATIC_LIBS``
|
||
to find and create :prop_tgt:`IMPORTED` target for static linkage.
|
||
|
||
``GLEW_VERBOSE``
|
||
to output a detailed log of this module.
|
||
|
||
Imported Targets
|
||
^^^^^^^^^^^^^^^^
|
||
|
||
This module defines the following :ref:`Imported Targets <Imported Targets>`:
|
||
|
||
|
||
``GLEW::glew``
|
||
The GLEW shared library.
|
||
``GLEW::glew_s``
|
||
The GLEW static library, if ``GLEW_USE_STATIC_LIBS`` is set to ``TRUE``.
|
||
``GLEW::GLEW``
|
||
Duplicates either ``GLEW::glew`` or ``GLEW::glew_s`` based on availability.
|
||
|
||
Result Variables
|
||
^^^^^^^^^^^^^^^^
|
||
|
||
This module defines the following variables:
|
||
|
||
``GLEW_INCLUDE_DIRS``
|
||
include directories for GLEW
|
||
``GLEW_LIBRARIES``
|
||
libraries to link against GLEW
|
||
``GLEW_SHARED_LIBRARIES``
|
||
libraries to link against shared GLEW
|
||
``GLEW_STATIC_LIBRARIES``
|
||
libraries to link against static GLEW
|
||
``GLEW_FOUND``
|
||
true if GLEW has been found and can be used
|
||
``GLEW_VERSION``
|
||
GLEW version
|
||
``GLEW_VERSION_MAJOR``
|
||
GLEW major version
|
||
``GLEW_VERSION_MINOR``
|
||
GLEW minor version
|
||
``GLEW_VERSION_MICRO``
|
||
GLEW micro version
|
||
|
||
#]=======================================================================]
|
||
|
||
include(FindPackageHandleStandardArgs)
|
||
|
||
|
||
if(APPLE)
|
||
find_package(OpenGL QUIET)
|
||
|
||
if(OpenGL_FOUND)
|
||
if(GLEW_VERBOSE)
|
||
message(STATUS "FindGLEW: Found OpenGL Framework.")
|
||
message(STATUS "FindGLEW: OPENGL_LIBRARIES: ${OPENGL_LIBRARIES}")
|
||
endif()
|
||
else()
|
||
if(GLEW_VERBOSE)
|
||
message(STATUS "FindGLEW: could not find GLEW library.")
|
||
endif()
|
||
return()
|
||
endif()
|
||
endif()
|
||
|
||
|
||
function(__glew_set_find_library_suffix shared_or_static)
|
||
if((UNIX AND NOT APPLE) AND "${shared_or_static}" MATCHES "SHARED")
|
||
set(CMAKE_FIND_LIBRARY_SUFFIXES ".so")
|
||
elseif((UNIX AND NOT APPLE) AND "${shared_or_static}" MATCHES "STATIC")
|
||
set(CMAKE_FIND_LIBRARY_SUFFIXES ".a")
|
||
elseif(APPLE AND "${shared_or_static}" MATCHES "SHARED")
|
||
set(CMAKE_FIND_LIBRARY_SUFFIXES ".dylib;.so")
|
||
elseif(APPLE AND "${shared_or_static}" MATCHES "STATIC")
|
||
set(CMAKE_FIND_LIBRARY_SUFFIXES ".a")
|
||
elseif(WIN32 AND "${shared_or_static}" MATCHES "SHARED")
|
||
set(CMAKE_FIND_LIBRARY_SUFFIXES ".lib")
|
||
elseif(WIN32 AND "${shared_or_static}" MATCHES "STATIC")
|
||
set(CMAKE_FIND_LIBRARY_SUFFIXES ".lib;.a;.dll.a")
|
||
endif()
|
||
|
||
set(CMAKE_FIND_LIBRARY_SUFFIXES "${CMAKE_FIND_LIBRARY_SUFFIXES}" PARENT_SCOPE)
|
||
if(GLEW_VERBOSE)
|
||
message(STATUS "FindGLEW: CMAKE_FIND_LIBRARY_SUFFIXES for ${shared_or_static}: ${CMAKE_FIND_LIBRARY_SUFFIXES}")
|
||
endif()
|
||
endfunction()
|
||
|
||
|
||
if(GLEW_VERBOSE)
|
||
if(DEFINED GLEW_USE_STATIC_LIBS)
|
||
message(STATUS "FindGLEW: GLEW_USE_STATIC_LIBS: ${GLEW_USE_STATIC_LIBS}.")
|
||
else()
|
||
message(STATUS "FindGLEW: GLEW_USE_STATIC_LIBS is undefined. Treated as FALSE.")
|
||
endif()
|
||
endif()
|
||
|
||
find_path(GLEW_INCLUDE_DIR GL/glew.h)
|
||
mark_as_advanced(GLEW_INCLUDE_DIR)
|
||
|
||
set(GLEW_INCLUDE_DIRS ${GLEW_INCLUDE_DIR})
|
||
|
||
if(GLEW_VERBOSE)
|
||
message(STATUS "FindGLEW: GLEW_INCLUDE_DIR: ${GLEW_INCLUDE_DIR}")
|
||
message(STATUS "FindGLEW: GLEW_INCLUDE_DIRS: ${GLEW_INCLUDE_DIRS}")
|
||
endif()
|
||
|
||
if("${CMAKE_GENERATOR_PLATFORM}" MATCHES "x64" OR "${CMAKE_GENERATOR}" MATCHES "Win64")
|
||
set(_arch "x64")
|
||
elseif("${CMAKE_GENERATOR_PLATFORM}" MATCHES "ARM64")
|
||
set(_arch "x64") # GLEW ships one header set; ARM64 uses the x64 import path
|
||
else()
|
||
set(_arch "Win32")
|
||
endif()
|
||
|
||
|
||
set(__GLEW_CURRENT_FIND_LIBRARY_SUFFIXES ${CMAKE_FIND_LIBRARY_SUFFIXES})
|
||
|
||
__glew_set_find_library_suffix(SHARED)
|
||
|
||
find_library(GLEW_SHARED_LIBRARY_RELEASE
|
||
NAMES GLEW glew glew32
|
||
PATH_SUFFIXES lib lib64 libx32 lib/Release/${_arch}
|
||
PATHS ENV GLEW_ROOT)
|
||
|
||
find_library(GLEW_SHARED_LIBRARY_DEBUG
|
||
NAMES GLEWd glewd glew32d
|
||
PATH_SUFFIXES lib lib64
|
||
PATHS ENV GLEW_ROOT)
|
||
|
||
|
||
__glew_set_find_library_suffix(STATIC)
|
||
|
||
find_library(GLEW_STATIC_LIBRARY_RELEASE
|
||
NAMES GLEW glew glew32s
|
||
PATH_SUFFIXES lib lib64 libx32 lib/Release/${_arch}
|
||
PATHS ENV GLEW_ROOT)
|
||
|
||
find_library(GLEW_STATIC_LIBRARY_DEBUG
|
||
NAMES GLEWds GLEWd glewd glewds glew32ds
|
||
PATH_SUFFIXES lib lib64
|
||
PATHS ENV GLEW_ROOT)
|
||
|
||
set(CMAKE_FIND_LIBRARY_SUFFIXES ${__GLEW_CURRENT_FIND_LIBRARY_SUFFIXES})
|
||
unset(__GLEW_CURRENT_FIND_LIBRARY_SUFFIXES)
|
||
|
||
include(SelectLibraryConfigurations)
|
||
|
||
select_library_configurations(GLEW_SHARED)
|
||
select_library_configurations(GLEW_STATIC)
|
||
|
||
if(NOT GLEW_USE_STATIC_LIBS)
|
||
set(GLEW_LIBRARIES ${GLEW_SHARED_LIBRARY})
|
||
else()
|
||
set(GLEW_LIBRARIES ${GLEW_STATIC_LIBRARY})
|
||
endif()
|
||
|
||
|
||
if(GLEW_VERBOSE)
|
||
message(STATUS "FindGLEW: GLEW_SHARED_LIBRARY_RELEASE: ${GLEW_SHARED_LIBRARY_RELEASE}")
|
||
message(STATUS "FindGLEW: GLEW_STATIC_LIBRARY_RELEASE: ${GLEW_STATIC_LIBRARY_RELEASE}")
|
||
message(STATUS "FindGLEW: GLEW_SHARED_LIBRARY_DEBUG: ${GLEW_SHARED_LIBRARY_DEBUG}")
|
||
message(STATUS "FindGLEW: GLEW_STATIC_LIBRARY_DEBUG: ${GLEW_STATIC_LIBRARY_DEBUG}")
|
||
message(STATUS "FindGLEW: GLEW_SHARED_LIBRARY: ${GLEW_SHARED_LIBRARY}")
|
||
message(STATUS "FindGLEW: GLEW_STATIC_LIBRARY: ${GLEW_STATIC_LIBRARY}")
|
||
message(STATUS "FindGLEW: GLEW_LIBRARIES: ${GLEW_LIBRARIES}")
|
||
endif()
|
||
|
||
|
||
# Read version from GL/glew.h file
|
||
if(EXISTS "${GLEW_INCLUDE_DIR}/GL/glew.h")
|
||
file(STRINGS "${GLEW_INCLUDE_DIR}/GL/glew.h" _contents REGEX "^VERSION_.+ [0-9]+")
|
||
if(_contents)
|
||
string(REGEX REPLACE ".*VERSION_MAJOR[ \t]+([0-9]+).*" "\\1" GLEW_VERSION_MAJOR "${_contents}")
|
||
string(REGEX REPLACE ".*VERSION_MINOR[ \t]+([0-9]+).*" "\\1" GLEW_VERSION_MINOR "${_contents}")
|
||
string(REGEX REPLACE ".*VERSION_MICRO[ \t]+([0-9]+).*" "\\1" GLEW_VERSION_MICRO "${_contents}")
|
||
set(GLEW_VERSION "${GLEW_VERSION_MAJOR}.${GLEW_VERSION_MINOR}.${GLEW_VERSION_MICRO}")
|
||
endif()
|
||
endif()
|
||
|
||
if(GLEW_VERBOSE)
|
||
message(STATUS "FindGLEW: GLEW_VERSION_MAJOR: ${GLEW_VERSION_MAJOR}")
|
||
message(STATUS "FindGLEW: GLEW_VERSION_MINOR: ${GLEW_VERSION_MINOR}")
|
||
message(STATUS "FindGLEW: GLEW_VERSION_MICRO: ${GLEW_VERSION_MICRO}")
|
||
message(STATUS "FindGLEW: GLEW_VERSION: ${GLEW_VERSION}")
|
||
endif()
|
||
|
||
find_package_handle_standard_args(GLEW
|
||
REQUIRED_VARS GLEW_INCLUDE_DIRS GLEW_LIBRARIES
|
||
VERSION_VAR GLEW_VERSION)
|
||
|
||
if(NOT GLEW_FOUND)
|
||
if(GLEW_VERBOSE)
|
||
message(STATUS "FindGLEW: could not find GLEW library.")
|
||
endif()
|
||
return()
|
||
endif()
|
||
|
||
|
||
if(NOT TARGET GLEW::glew AND NOT GLEW_USE_STATIC_LIBS)
|
||
if(GLEW_VERBOSE)
|
||
message(STATUS "FindGLEW: Creating GLEW::glew imported target.")
|
||
endif()
|
||
|
||
add_library(GLEW::glew UNKNOWN IMPORTED)
|
||
|
||
set_target_properties(GLEW::glew
|
||
PROPERTIES INTERFACE_INCLUDE_DIRECTORIES "${GLEW_INCLUDE_DIRS}")
|
||
|
||
if(APPLE)
|
||
if(CMAKE_VERSION VERSION_GREATER_EQUAL "4.0")
|
||
set_target_properties(GLEW::glew
|
||
PROPERTIES INTERFACE_LINK_LIBRARIES "-framework OpenGL")
|
||
else()
|
||
set_target_properties(GLEW::glew
|
||
PROPERTIES INTERFACE_LINK_LIBRARIES OpenGL::GL)
|
||
endif()
|
||
endif()
|
||
|
||
if(GLEW_SHARED_LIBRARY_RELEASE)
|
||
set_property(TARGET GLEW::glew
|
||
APPEND
|
||
PROPERTY IMPORTED_CONFIGURATIONS RELEASE)
|
||
|
||
set_target_properties(GLEW::glew
|
||
PROPERTIES IMPORTED_LOCATION_RELEASE "${GLEW_SHARED_LIBRARY_RELEASE}")
|
||
endif()
|
||
|
||
if(GLEW_SHARED_LIBRARY_DEBUG)
|
||
set_property(TARGET GLEW::glew
|
||
APPEND
|
||
PROPERTY IMPORTED_CONFIGURATIONS DEBUG)
|
||
|
||
set_target_properties(GLEW::glew
|
||
PROPERTIES IMPORTED_LOCATION_DEBUG "${GLEW_SHARED_LIBRARY_DEBUG}")
|
||
endif()
|
||
|
||
elseif(NOT TARGET GLEW::glew_s AND GLEW_USE_STATIC_LIBS)
|
||
if(GLEW_VERBOSE)
|
||
message(STATUS "FindGLEW: Creating GLEW::glew_s imported target.")
|
||
endif()
|
||
|
||
add_library(GLEW::glew_s UNKNOWN IMPORTED)
|
||
|
||
set_target_properties(GLEW::glew_s
|
||
PROPERTIES INTERFACE_INCLUDE_DIRECTORIES "${GLEW_INCLUDE_DIRS}")
|
||
|
||
set_target_properties(GLEW::glew_s PROPERTIES INTERFACE_COMPILE_DEFINITIONS GLEW_STATIC)
|
||
|
||
if(APPLE)
|
||
if(CMAKE_VERSION VERSION_GREATER_EQUAL "4.0")
|
||
set_target_properties(GLEW::glew_s
|
||
PROPERTIES INTERFACE_LINK_LIBRARIES "-framework OpenGL")
|
||
else()
|
||
set_target_properties(GLEW::glew_s
|
||
PROPERTIES INTERFACE_LINK_LIBRARIES OpenGL::GL)
|
||
endif()
|
||
endif()
|
||
|
||
if(GLEW_STATIC_LIBRARY_RELEASE)
|
||
set_property(TARGET GLEW::glew_s
|
||
APPEND
|
||
PROPERTY IMPORTED_CONFIGURATIONS RELEASE)
|
||
|
||
set_target_properties(GLEW::glew_s
|
||
PROPERTIES IMPORTED_LOCATION_RELEASE "${GLEW_STATIC_LIBRARY_RELEASE}")
|
||
endif()
|
||
|
||
if(GLEW_STATIC_LIBRARY_DEBUG)
|
||
set_property(TARGET GLEW::glew_s
|
||
APPEND
|
||
PROPERTY IMPORTED_CONFIGURATIONS DEBUG)
|
||
|
||
set_target_properties(GLEW::glew_s
|
||
PROPERTIES IMPORTED_LOCATION_DEBUG "${GLEW_STATIC_LIBRARY_DEBUG}")
|
||
endif()
|
||
endif()
|
||
|
||
if(NOT TARGET GLEW::GLEW)
|
||
if(GLEW_VERBOSE)
|
||
message(STATUS "FindGLEW: Creating GLEW::GLEW imported target.")
|
||
endif()
|
||
|
||
add_library(GLEW::GLEW UNKNOWN IMPORTED)
|
||
|
||
set_target_properties(GLEW::GLEW
|
||
PROPERTIES INTERFACE_INCLUDE_DIRECTORIES "${GLEW_INCLUDE_DIRS}")
|
||
|
||
if(APPLE)
|
||
if(CMAKE_VERSION VERSION_GREATER_EQUAL "4.0")
|
||
set_target_properties(GLEW::GLEW
|
||
PROPERTIES INTERFACE_LINK_LIBRARIES "-framework OpenGL")
|
||
else()
|
||
set_target_properties(GLEW::GLEW
|
||
PROPERTIES INTERFACE_LINK_LIBRARIES OpenGL::GL)
|
||
endif()
|
||
endif()
|
||
|
||
if(TARGET GLEW::glew)
|
||
if(GLEW_SHARED_LIBRARY_RELEASE)
|
||
set_property(TARGET GLEW::GLEW
|
||
APPEND
|
||
PROPERTY IMPORTED_CONFIGURATIONS RELEASE)
|
||
|
||
set_target_properties(GLEW::GLEW
|
||
PROPERTIES IMPORTED_LOCATION_RELEASE "${GLEW_SHARED_LIBRARY_RELEASE}")
|
||
endif()
|
||
|
||
if(GLEW_SHARED_LIBRARY_DEBUG)
|
||
set_property(TARGET GLEW::GLEW
|
||
APPEND
|
||
PROPERTY IMPORTED_CONFIGURATIONS DEBUG)
|
||
|
||
set_target_properties(GLEW::GLEW
|
||
PROPERTIES IMPORTED_LOCATION_DEBUG "${GLEW_SHARED_LIBRARY_DEBUG}")
|
||
endif()
|
||
|
||
elseif(TARGET GLEW::glew_s)
|
||
if(GLEW_STATIC_LIBRARY_RELEASE)
|
||
set_property(TARGET GLEW::GLEW
|
||
APPEND
|
||
PROPERTY IMPORTED_CONFIGURATIONS RELEASE)
|
||
|
||
set_target_properties(GLEW::GLEW
|
||
PROPERTIES IMPORTED_LOCATION_RELEASE "${GLEW_STATIC_LIBRARY_RELEASE}"
|
||
INTERFACE_COMPILE_DEFINITIONS GLEW_STATIC)
|
||
endif()
|
||
|
||
if(GLEW_STATIC_LIBRARY_DEBUG AND GLEW_USE_STATIC_LIBS)
|
||
set_property(TARGET GLEW::GLEW
|
||
APPEND
|
||
PROPERTY IMPORTED_CONFIGURATIONS DEBUG)
|
||
|
||
set_target_properties(GLEW::GLEW
|
||
PROPERTIES IMPORTED_LOCATION_DEBUG "${GLEW_STATIC_LIBRARY_DEBUG}"
|
||
INTERFACE_COMPILE_DEFINITIONS GLEW_STATIC)
|
||
endif()
|
||
|
||
elseif(GLEW_VERBOSE)
|
||
message(WARNING "FindGLEW: no `GLEW::glew` or `GLEW::glew_s` target was created. Something went wrong in FindGLEW target creation.")
|
||
endif()
|
||
endif()
|