52c2a85d28
* Get libslic3r tests closer to passing I can't get geometry tests to do anything useful. I've added extra output, but it hasn't helped me figure out why they don't work yet. That's also probably the last broken 3mf test doesn't work. The config tests were mostly broken because of config name changes. The placeholder_parser tests have some things that may-or-may-not still apply to Orca. * Vendor a 3.x version of Catch2 Everything is surely broken at this point. * Allow building tests separately from Orca with build_linux.sh * Remove unnecessary log message screwing up ctest Same solution as Prusaslicer * Make 2 TriangleMesh methods const Since they can be. * Move method comment to the header where it belongsc * Add indirectly-included header directly Transform3d IIRC * libslic3r tests converted to Catch2 v3 Still has 3 failing tests, but builds and runs. * Disable 2D convex hull test and comment what I've learned Not sure the best way to solve this yet. * Add diff compare method for DynamicConfig Help the unit test report errors better. * Perl no longer used, remove comment line * Clang-format Config.?pp So difficult to work with ATM * Remove cpp17 unit tests Who gives a shit * Don't need explicit "example" test We have lots of tests to serve as examples. * Leave breadcrumb to enable sla_print tests * Fix serialization of DynamicConfig Add comments to test, because these code paths might not be even used anymore. * Update run_unit_tests to run all the tests By the time I'm done with the PR all tests will either excluded by default or passing, so just do all. * Update how-to-test now that build_linux.sh builds tests separately * Update cmake regenerate instructions Read this online; hopefully works. * Enable slic3rutils test with Catch2 v3 * Port libnest2d and fff_print to Catch2 v3 They build. Many failing. * Add slightly more info to Objects not fit on bed exception * Disable failing fff_print tests from running They're mostly failing for "objects don't fit on bed" for an infinite-sized bed. Given infinite bed is probably only used in tests, it probably was incidentally broken long ago. * Must checkout tests directory in GH Actions So we get the test data * Missed a failing fff_print test * Disable (most/all) broken libnest2d tests Trying all, not checking yet though * Fix Polygon convex/concave detection tests Document the implementation too. Reorganize the tests to be cleaner. * Update the test script to run tests in parallel * Get sla_print tests to build Probably not passing * Don't cause full project rebuild when updating test CMakeLists.txts * Revert "Clang-format Config.?pp" This reverts commit 771e4c0ad2fdbaa26a8fee77030650afacdc5083. --------- Co-authored-by: SoftFever <softfeverever@gmail.com>
53 lines
1.6 KiB
CMake
53 lines
1.6 KiB
CMake
|
|
# Copyright Catch2 Authors
|
|
# Distributed under the Boost Software License, Version 1.0.
|
|
# (See accompanying file LICENSE.txt or copy at
|
|
# https://www.boost.org/LICENSE_1_0.txt)
|
|
|
|
# SPDX-License-Identifier: BSL-1.0
|
|
|
|
# Indirection for CatchShardTests that allows us to delay the script
|
|
# file generation until build time.
|
|
|
|
# Expected args:
|
|
# * TEST_BINARY - full path to the test binary to run sharded
|
|
# * CTEST_FILE - full path to ctest script file to write to
|
|
# * TARGET_NAME - name of the target to shard (used for test names)
|
|
# * SHARD_COUNT - number of shards to split the binary into
|
|
# Optional args:
|
|
# * REPORTER_SPEC - reporter specs to be passed down to the binary
|
|
# * TEST_SPEC - test spec to pass down to the test binary
|
|
|
|
if(NOT EXISTS "${TEST_BINARY}")
|
|
message(FATAL_ERROR
|
|
"Specified test binary '${TEST_BINARY}' does not exist"
|
|
)
|
|
endif()
|
|
|
|
set(other_args "")
|
|
if(TEST_SPEC)
|
|
set(other_args "${other_args} ${TEST_SPEC}")
|
|
endif()
|
|
if(REPORTER_SPEC)
|
|
set(other_args "${other_args} --reporter ${REPORTER_SPEC}")
|
|
endif()
|
|
|
|
# foreach RANGE in cmake is inclusive of the end, so we have to adjust it
|
|
math(EXPR adjusted_shard_count "${SHARD_COUNT} - 1")
|
|
|
|
file(WRITE "${CTEST_FILE}"
|
|
"string(RANDOM LENGTH 8 ALPHABET \"0123456789abcdef\" rng_seed)\n"
|
|
"\n"
|
|
"foreach(shard_idx RANGE ${adjusted_shard_count})\n"
|
|
" add_test(${TARGET_NAME}-shard-" [[${shard_idx}]] "/${adjusted_shard_count}\n"
|
|
" ${TEST_BINARY}"
|
|
" --shard-index " [[${shard_idx}]]
|
|
" --shard-count ${SHARD_COUNT}"
|
|
" --rng-seed " [[0x${rng_seed}]]
|
|
" --order rand"
|
|
"${other_args}"
|
|
"\n"
|
|
" )\n"
|
|
"endforeach()\n"
|
|
)
|